***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Dec 30, 2020                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt PDZ8P2B A K 
.param
+vc0 = 1.046e-11	 vc1 = 6.526e-11	 vc2 = 1.000		vc3 = 1.220e-13		 vc4 = 1.840
+tc1 = 7.081e-3		 tc2 = 1.791e-2		 tc3 = 6.701e-3		tc4 = 3.021e-3
.func irexp(v) {(vc0+vc1*v^vc2)*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))+(vc3*exp(vc4*v))*(1.0+tc3*(temp-25)*exp(tc4*(temp-25)))}
d1 A K zener
g1 K A value = {irexp(v(K,A))}
.model zener d
***** flag parameter *****
+level = 1                     
***** dc model parameter *****
+ is = 6.429e-16	   n = 1.009		  rs = 1.372e-1
+ibv = 5e-3		 nbv = 1.0		  bv = 8.19
+ikf = 5.896e-1
***** capacitance parameter *****
+cjo = 1.307e-10	   m = 3.197e-1		  vj = 5.805e-1 
+ fc = 0.5
***** temperature coefficient *****
+tnom = 25		  eg = 1.083		 xti = 3
+trs1 = 2.056e-4	trs2 = -5.033e-6	tikf = 5.0e-3
+tbv1 = 4.729e-4	tbv2 = 1.875e-7	
.ends PDZ8P2B
*$
